Wenn man des öfteren zwischen zwei verschiedenen Gateways unter Windows umschalten muss, z.B. durch zwei verschiedene Internetanschlüsse, ist es lästig die immer über die Netzwerkeinstellungen vorzunehmen. Mit folgendem Batch-Skript kann man die Einstellungen automatisch vornehmen lassen:

@echo off

rem Lokale Netzwerkkonfiguration
rem ============================================================
set network_name=LAN-Verbindung
set local_ip=192.168.1.20
set subnet_mask=255.255.255.0

rem Gateway und DNS
rem ============================================================
set dsl_gateway=192.168.1.1
set dsl_primary_dns=8.8.8.8
set dsl_secondary_dns=192.168.1.1
rem ============================================================
set lte_gateway=192.168.1.2
set lte_primary_dns=8.8.8.8
set lte_secondary_dns=192.168.1.2
rem ============================================================


rem SKRIPT:
rem ============================================================
set /P w= [1]LTE / [2]DSL? 
if /I "%w%"=="1" goto LTE
if /I "%w%"=="2" goto DSL
echo Fehler: [%w%]
goto ende
 
:LTE
	echo.**** Aktiviere LTE Gateway ****
	echo.**** Setze IP von %network_name% auf %local_ip% / Gateway: %lte_gateway% ****
	netsh interface ipv4 set address "%network_name%" static %local_ip% %subnet_mask% %lte_gateway%
	ping -n 5 127.0.0.1 > nul
	echo.**** Setze primaeren DNS-Server %lte_primary_dns% ****
	netsh interface ipv4 set dns name="%network_name%" source=static addr=%lte_primary_dns% register=PRIMARY
	echo.**** Setze sekundaeren DNS-Server %lte_secondary_dns% ****
	netsh interface ipv4 add dns name="%network_name%" addr=%lte_secondary_dns% index=2
	rem 2 sekunden pause
	ping -n 2 127.0.0.1 > nul
	echo.**** ping auf google.de ****
	ping -n 1 google.de
	goto ende
 
:DSL
	echo.**** Aktiviere DSL Gateway ****
	echo.**** Setze IP von %network_name% auf %local_ip% / Gateway: %dsl_gateway% ****
	netsh interface ipv4 set address "%network_name%" static %local_ip% %subnet_mask% %dsl_gateway%
	ping -n 5 127.0.0.1 > nul
	echo.**** Setze primaeren DNS-Server %dsl_primary_dns% ****
	netsh interface ipv4 set dns name="%network_name%" source=static addr=%dsl_primary_dns% register=PRIMARY
	echo.**** Setze sekundaeren DNS-Server %dsl_secondary_dns% ****
	netsh interface ipv4 add dns name="%network_name%" addr=%dsl_secondary_dns% index=2
	rem 2 sekunden pause
	ping -n 2 127.0.0.1 > nul
	echo.**** ping auf google.de ****
	ping -n 1 google.de
	goto ende
  
:ende
rem pause